Pāriet uz saturu

Sīkdatņu iestatījumi

Izvēlieties, kāda veida sīkdatnes atļaujat. Savu izvēli varat jebkurā laikā mainīt sadaļā Sīkdatņu iestatījumi katras lapas apakšā. Privātuma politika

Nepieciešamās

Vienmēr ieslēgtas

Vajadzīgas, lai pieteiktos, saglabātu grozu un atcerētos Jūsu izvēles. Tās vienmēr ir ieslēgtas.

Kuras sīkdatnes?
  • weboke_sessie, weboke_klant, weboke_remember: Jūsu sesija un pieteikšanās saglabāšana
  • weboke_basket: Jūsu grozs
  • wkBtwIncl: cenu rādīšana ar PVN vai bez PVN
  • wok_cookies: Jūsu sīkdatņu izvēle, 12 mēneši

Mēra, kura reklāma noved pie apmeklējuma vai pasūtījuma, lai mēs nemaksātu par reklāmām, kas neko nedod.

Kuras sīkdatnes?
  • Google Ads ar Google Tag Manager (_gcl_au, _gcl_aw), līdz 90 dienām
  • OpenAI Ads, reklāmas ChatGPT
  • wok_aff: caur kuru partneri nonācāt pie mums (partneru programma), 60 dienas

4,6

Valsts un valoda

Katrai valstij ir sava vietne ar attiecīgās valsts cenām un PVN.

Skatīt

Twee lijsten vergelijken: wie staat er wel in de ene en niet in de andere?

Šis raksts vēl nav tulkots. Jūs lasāt holandiešu valodas versiju.

De ledenlijst tegen de betalingen, de klanten van vorig jaar tegen die van dit jaar, de voorraadlijst tegen de bestelling: je wilt weten wie er in de ene lijst staat en niet in de andere. Dubultus klientus atrast un dzēst zoekt dubbelen binnen één lijst; hier vergelijk je twee lijsten met elkaar.

Als voorbeeld nemen we Bakkerij De Korenaar met twee werkbladen: Klanten2025 met de e-mailadressen van vorig jaar in A2:A8, en Klanten2026 met die van dit jaar in A2:A7.

Manier 1: een hulpkolom met weg of blijft

Typ op het werkblad Klanten2025 in B2:

=ALS(AANTAL.ALS(Klanten2026!$A$2:$A$7;A2)=0;"weg";"blijft")

Trek de formule door tot de laatste klant. AANTAL.ALS telt hoe vaak het adres in de lijst van 2026 voorkomt. Is dat 0, dan is de klant weg. Daarna kun je op kolom B filteren of sorteren (zie Šķirošana un filtrēšana).

De dollartekens zijn belangrijk: zonder dollartekens schuift het bereik in de andere lijst mee bij doortrekken, en vallen de bovenste adressen er onderaan uit.

Manier 2: een lijst met alleen de verschillen

Op een apart werkblad maakt FILTER in één keer een lijst van alle vertrokken klanten:

=FILTER(Klanten2025!A2:A8;AANTAL.ALS(Klanten2026!A2:A7;Klanten2025!A2:A8)=0;"niemand weg")

Hier krijgt AANTAL.ALS een hele lijst als tweede onderdeel en telt het voor elk adres van 2025 tegelijk. FILTER houdt de adressen over waarvoor dat 0 is. De nieuwe klanten vind je door de lijsten om te draaien:

=FILTER(Klanten2026!A2:A7;AANTAL.ALS(Klanten2025!A2:A8;Klanten2026!A2:A7)=0;"niemand nieuw")

Vertrokken en nieuwe klanten naast elkaar
Vertrokken klanten (1) en nieuwe klanten (2), elk met één FILTER-formule

Wie in maar één van beide lijsten staat, nieuw of vertrokken, krijg je met:

=UNIEK(VERT.STAPELEN(Klanten2025!A2:A8;Klanten2026!A2:A7);;1)

VERT.STAPELEN zet de twee lijsten onder elkaar. UNIEK met een 1 als derde onderdeel houdt alleen de waarden over die precies één keer voorkomen. Staat een adres binnen één lijst al dubbel, maak die lijst dan eerst uniek: =UNIEK(VERT.STAPELEN(UNIEK(Klanten2025!A2:A8);UNIEK(Klanten2026!A2:A7));;1).

Manier 3: kleuren in plaats van lijsten

  1. Selecteer op het werkblad Klanten2025 de adressen, A2:A8.
  2. Kies op het tabblad Start Conditionele opmaak, Nieuwe regel, soort Formule.
  3. Typ =AANTAL.ALS(Klanten2026!$A$2:$A$7;$A2)=0, kies een opvulkleur en klik op OK.

Een verwijzing naar een ander werkblad in een opmaakregel werkt in Euro-Office gewoon; in oude Excel-versies moest dat via een benoemde naam.

Vertrokken klanten gekleurd
Adressen die in 2026 niet meer voorkomen kleuren oranje; kolom B zegt weg of blijft

Valkuilen

  • Spaties: "info@dekorenaar.nl " met een spatie erachter is voor de spreadsheet een ander adres. Ruim spaties eerst op met SPATIES.WISSEN in een hulpkolom.
  • Lege cellen in een bereik tellen ook mee als waarde. Neem dus alleen de rijen met gegevens, of filter lege cellen weg met <>"".
  • Getallen tegen tekst: vergelijk je klantnummers en staat het nummer in de ene lijst als tekst (links in de cel) en in de andere als getal, dan vinden ze elkaar niet. Zie VLOOKUP atgriež #N/A: kā to novērst.
  • Typ geen WAAR zonder haakjes als derde onderdeel van UNIEK; Euro-Office kent alleen TRUE, WAAR() of 1 (zie Formulas pārņemšana no Excel: angļu funkciju nosaukumi un semikols).

Lūdzu, uzgaidiet…

Iestatiet savus domēnus

Katram domēnam norādiet vārdu serverus, piesaisti hostingam un to, kurš būs turētājs.

Ielādē Jūsu domēnus…